The Right Way to Change Word Styles to Direct Formatting

One of the best ways to ensure consistent formatting in a Word document is to use styles.¹ But you might also need to be able to turn these styles into “direct” formatting.

Background

If you apply a style to text, the text will be formatted as the style specifies (e.g., a first-level heading, a block quotation). This helps you avoid forgetting something like applying italics or bold here or there in a document as you’ve done elsewhere. So, using styles helps make your document formatting more consistent.

If you need to change the formatting, just modify the style. The formatting for all text with that style will then update accordingly. There’s no need to update every place the style occurs individually.

Challenges with Styles

So far so good, but Word’s style definitions may not always transfer completely from one computer to another as you’d expect. In addition, if you have multiple documents—say, from multiple different contributors—each of those documents might have its own separate definitions for the same styles or its own styles that it uses but none of the other documents does.

For these kinds of reasons, constructing one document out of several can be a real headache. So, multiple publishers follow a rule similar to the one that SBL Press adopts, saying,

Do not use your word processor’s style option to mark different elements of the text (body text, headings, subheads).²

So, if you’re writing for SBL Press or another publisher with similar requirements, does this mean you can’t use styles? Or, if you do use styles, do you consign yourself to hours more editing work in order to remove them when you’re preparing to send off a typescript?

Fortunately, no. There are ways to convert Word styles into the direct formatting that SBL Press and others want. Here are 10 steps to do just that.³

1. Add two macros to Word.

If your document uses parenthetical citations, you can just do the steps below involving RTF and WordPad.

If your document uses footnotes or endnotes, however, you’ll lose them in a subsequent step in this process if they’re still structured as proper footnotes or endnotes (e.g., using Word’s Insert Footnote or Insert Endnote option). To avoid this, you’ll want to start by creating two macros in Word. A “macro” is a small program that runs inside a Microsoft Office application like Word.

Don’t worry. You don’t need to know anything about writing a macro. Assuming you use Office 365, just open Word, and go to View > Macros > Create to get started.⁴

Scroll to the bottom of any macro list that comes up. Press Enter or click on a blank line after anything else in the window.

1.1 UnLinkNotes

Then, copy and paste there the following:

Sub UnLinkNotes()
Application.ScreenUpdating = False
Dim nRng As Range, fNote As Footnote, nRef As String
With ActiveDocument
  For Each fNote In .Footnotes
    With fNote
      With .Reference.Characters.First
        .InsertAfter "]"
        .Characters.Last.Font.Superscript = True
        .Collapse wdCollapseStart
        .InsertCrossReference wdRefTypeFootnote, wdFootnoteNumberFormatted, fNote.Index
        nRef = .Characters.First.Fields(1).Result
        .Characters.First.Fields(1).Unlink
        .InsertBefore "["
        .Characters.First.Font.Superscript = True
      End With
      .Range.Cut
    End With
    Set nRng = .Range
    With nRng
      .Collapse wdCollapseEnd
      .End = .End - 1
      If .Characters.Last <> Chr(12) Then .InsertAfter vbCr
      .InsertAfter nRef & " "
      With .Paragraphs.Last.Range
        .Style = "Footnote Text"
        .Words.First.Style = "Footnote Reference"
      End With
      .Collapse wdCollapseEnd
      .Paste
      If .Characters.Last = Chr(12) Then .InsertAfter vbCr
    End With
  Next
  For Each fNote In .Footnotes
    fNote.Delete
  Next
End With
Set nRng = Nothing
Application.ScreenUpdating = True
End Sub

1.2 ReLinkNotes

After this, press Enter to go to a new line again. Then, copy and paste the following:

Sub ReLinkNotes()
Dim i As Integer, j As Integer, k As Integer, l As Integer, FtRng As Range
Application.ScreenUpdating = False
With ActiveDocument
  Set FtRng = Selection.Range
  With FtRng
    .Style = "Footnote Text"
    With .Find
      .ClearFormatting
      .Replacement.ClearFormatting
      .Text = "\[([0-9]{1,})\]"
      .Replacement.Text = "\1"
      .Forward = True
      .Wrap = wdFindStop
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchAllWordForms = False
      .MatchSoundsLike = False
      .MatchWildcards = True
      .Execute Replace:=wdReplaceAll
    End With
    k = .Paragraphs(1).Range.Words(1) - 1
    j = k
    l = ActiveDocument.Footnotes.Count - k
    For i = 1 To .Paragraphs.Count
      If .Paragraphs(i).Range.Words(1) = j + 1 Then
        j = j + 1
      End If
    Next i
  End With
  For i = k + 1 To j
    StatusBar = "Finding Footnote Location: " & i + l
    With .Content.Find
      .Text = "[" & i & "]"
      .Font.Superscript = True
      .MatchWholeWord = True
      .MatchWildcards = False
      .Execute
      If .Found = True Then
        .Parent.Select
        With Selection
          .Delete
          .Footnotes.Add Range:=Selection.Range, Text:=""
        End With
      End If
    End With
  Next i
  With FtRng
    For i = k + 1 To j
      StatusBar = "Transferring Footnote: " & i + l
      With .Paragraphs(1).Range
        .Cut
        With ActiveDocument.Footnotes(i + l).Range
          .Paste
          .Words(1).Delete
          .Characters.Last.Delete
        End With
      End With
    Next i
  On Error Resume Next
  End With
  Set FtRng = Nothing
End With
Application.ScreenUpdating = True
End Sub

Click the save button, and you close the Microsoft Visual Basic for Applications window.

Congratulations! You just added two macros to Word. One is tilted UnLinkNotes. The other is titled ReLinkNotes.

You only have to do this step once.⁵ Now when you go to View > Macros, you should see both UnLinkNotes and ReLinkNotes in the macro list.⁶

2. Save a backup copy of your file.

Just in case something goes wrong, make a backup copy of your document before you run the first macro. That way, you don’t risk losing anything in the unlikely event that something goes awry.

In most cases, this process goes without issue. But for instance, if you have text where you regularly insert ligatures manually (e.g., some Syriac quotations), you may find that this process removes those ligatures or otherwise breaks the direction your text flows (e.g., turning some right-to-left text into left-to-right text).

So, it’s always good to have a backup copy of your document. That way, you can easily double check that text. And if anything goes badly wrong with it, you can skip the task of repairing your document. Instead, you can just focus on other ways of meeting your publisher’s submission requirements.

3. Unlink your footnotes.

In order to move Word styles to direct formatting, you’ll need to open the file in WordPad. Unfortunately, WordPad doesn’t support footnotes.

So, you need some way to manipulate the document without losing your footnotes. To avoid this, you need to “unlink” the notes and save them as text that appears in the body, or main page area, at the end of your document.⁷

If your document uses endnotes, you’ll first need to convert them to footnotes. You can do so easily from the References tab by clicking the southeast arrow in the Footnotes section. Then, in the Footnote and Endnote dialog box,

1. click Convert…,
2. choose Convert all endnotes to footnotes, and
3. click OK.

To unlink your footnotes, go to View > Macros. Then, click the UnLinkNotes macro, and click Run.

Be patient. Depending on how long your document is, how many footnotes you have, and how fast your computer is, unlinking the notes may take some time.

When the screen refreshes and you see “^[1]” where the anchor was for your first footnote, the macro should be done.

4. Save your file in RTF, and use WordPad to extraneous styles while preserving formatting.

4.1. Save your document as an RTF file.

If it isn’t already, save your file in RTF (“Rich Text Format”). RTF is much like the default DOC(X) format for Word but more basic.

You can do this in Word for Office 365 by going to the File tab > Save a Copy.⁸ Input your desired file name, and choose where you want to save the file.

From the file type dropdown box, choose to save the file in Rich Text Format (*.rtf). Then, click Save.

4.2. Reinstall WordPad (if needed).

Before 2024, Microsoft Windows came with WordPad preinstalled. During 2024, however, versions of Windows 11 updated past a certain point have WordPad removed.

If this situation applies to you, you need to reinstall WordPad. But as with adding the macros I’ve mentioned above, you’ll only need to do this step once.

(Incidentally, if you identify a workable alternative to WordPad that works on Windows, MacOS, or Linux, please leave a comment about that here.)

You can now download WordPad from this archive of stock Windows programs that have now been removed from the operating system.⁹ Once the download completes, run the installer, and you should find WordPad in your Start menu again.

4.3. Open and resave your RTF file in WordPad.

Open your RTF file in WordPad. Make some minor change to the file (e.g., adding a space somewhere). Save the file. Delete your change, and save the file again.

This process will get WordPad to overwrite the existing RTF file and all Word’s styles in it. When WordPad overwrites the file, it will change all the formatting to “direct” formatting and reset the style for the whole document to “Normal.”

So, for instance, you won’t have a “Heading 1” style in use any more. But WordPad will retain the formatting for the Heading 1 style. That way, the text will still display as you had it formatted before removing the style.

Once you’ve completed this step, close WordPad.

5. Open your RTF in Word, and resave it in whatever format you need.

Open your RTF file in Word. Resave it in whatever format you actually want the file in (e.g., DOC, DOCX). To do so, open it in Word, and use the same process as in step 4.1 above.

When you choose the file format, just choose whatever format besides RTF that you actually need.

6. Check for a stray period, and edit accordingly.

When you ran the UnLinkNotes macro, the final punctuation mark (probably a period) in your conclusion or bibliography may have gotten moved to after your last footnote. If so, you may see no punctuation at the end of your conclusion and two at the end of your last footnote.

If this has happened, add a period after your conclusion, and delete one of the two after your last footnote.

7. Check for intra-note paragraph breaks.

The ReLinkNotes macro assumes you have one paragraph per note. There are times, however, when this assumption might not hold. For instance, you might have a note that includes a block quotation. Or you might have a note that includes multiple full paragraphs.

In such cases, you should consider whether, compositionally, your this presentation is best for your readers. Or would it be better if you integrated this note material into the main text?

If you decide to retain a situation where you have a paragraph break inside a footnote, you’ll come into a problem with the ReLinkNotes macro. That is, the macro will fail with Run-time error '13'.

So, in this scenario, you’ll need to temporarily adjust your document. Replace your intra-note paragraph breaks with some string of characters that you use nowhere else in your document (e.g., “PARAGRAPHBREAK”).

Once you have these replacements made, proceed to the next step in the process.

8. Select your footnotes.

Scroll to the end of the document, and find the “¹” that indicates the start of the text of your first footnote.

Use the mouse or keyboard to select the “¹” and all the following text in all of your footnotes. That is, at the end of this step, you should have all your footnotes selected at the same time. You need all of this text selected so that the ReLinkNotes macro knows which text to move into footnotes again.

If you forget this step, you’ll see the same error message as above. In this case, though, you don’t need to do anything to your document. Just select all of the text for all of your notes, and try running the macro again.

9. Relink your footnotes.

Relink your footnotes by going to View > Macros. Click the ReLinkNotes macro, and click Run.

Be patient. Depending on how long your document is, how many footnotes you have, and how fast your computer is, relinking the notes may take some time.

10. Modify your notes as needed in bulk.

After the ReLinkNotes macro finishes, your footnotes will be back in their places and all flush with the left-hand margin. You’ll need to tend to a few items with them, but you can handle most of these steps pretty easily in bulk.

10.1. Change footnotes to endnotes.

If you want endnotes instead of footnotes, convert your footnotes to endnotes by using the process described above. In the Convert Notes dialog box, just choose Convert all footnotes to endnotes. After you convert the notes, you may need to come back to the Footnote and Endnote dialog box to choose to have Arabic rather than Roman numerals for your endnotes.

10.2. Update your notes’ formatting.

When the macro recreates your notes, it will keep the formatting you have for different parts of the notes (e.g., italics). But Word defaults to giving footnotes a Footnote Text style rather than the Normal style. And if you change your footnotes to endnotes, they’ll receive the Endnote Text style.

To ensure your notes only use the Normal style, select them all (e.g., click somewhere in one note, and do Ctrl+A or Cmd+A). Then, select the Normal style option on the Home tab.

If your Normal style isn’t formatted exactly as your publisher wants (e.g., font face, size), now’s the time to make those changes to your notes. Your notes should still all be selected from the last step. But if not, select them all again.

Then, manually adjust the formatting as needed for your notes’

• change the font face,
• first-line indentation,
• line spacing, or
• spacing between each other.

10.3. Restore intra-note paragraph breaks.

If you have any intra-note paragraph breaks you want to restore, you can easily do that at this point. Just run a find (e.g., for “PARAGRAPHBREAK”) and replace (i.e., for “^p”) to restore the breaks.

After you do so, you check the formatting of any block quotations you’ve used in your notes. They’ll probably need to have their formatting touched up (e.g., by indenting all lines from the left, rather than the first line only).

Otherwise, your document should be all set!

Conclusion

After these steps, you’ll have a document with the only Normal style, and your document will use direct formatting in use throughout. If you need to shift styles to direct formatting in another document, just repeat steps 2–9 above for that document.

By following this process, you’ll get the benefit of formatting consistency by using styles. You’ll also save yourself a good amount of work if you need to remove those styles as you prepare to submit your typescript. Happy editing!

You're ready to fill your toolbox.

Do you want to keep honing your craft?Yes, send me other resourcesNo, just send me the toolbox guide

Send me the complimentary guide

I respect your privacy. You choose what you receive. Unsubscribe any time.

1. Header image provided by NordWood Themes. ↩︎
2. SBL Handbook of Style (affiliate disclosure), §2.1.3. ↩︎
3. For pointing me in the right direction when I was initially mulling over this question, I’m very grateful to the MS Office Forums. ↩︎
4. If you use an earlier version of Word, the way you get to the macros tool may be a bit different. If you have difficulty finding it, try Googling for “how to create a macro in Microsoft Word [your Word year or version].” ↩︎
5. You will, however, need to perform this step once per computer. So, if you start using a new machine, just come back to this post. You can then find the macro text to copy and paste into Word on your new machine. ↩︎
6. Greg Maxey has worked out a different macro that will also relink footnotes, but this macro may require a bit more preparatory work than the one recommended here. ↩︎
7. If you use Zotero or a similar citation manager, you may also want to unlink your citations before going through this process. ↩︎
8. If you use an earlier version of Word and have difficulty saving your file in RTF, try Googling for “how to save a file in RTF in Microsoft Word [your Word year or version].” ↩︎
9. E.g., see Sergey Tkachenko, “Get Classic WordPad for Windows 11,” Winaero, 15 January 2024; Vivek Y., “How to Install WordPad on Windows 11, 10 (in the Right Way),” Hackernoon, 23 July 2024. ↩︎